﻿! door_panel_M /modified by VL 3/1/94/
! internal macro: door_int_frame
! a=width, b=height, c=thickness, d= panel frame width,
! e=fill material, f=internal frame width of fill, 
i=(a-4*d)/3     ! horiz. size of panes
j=(b-4*d)/7     ! vert.size of panes
f=1"
g=f*d/2/j+sqr(f*f+(d*d*f*f)/(4*j*j))        ! internal edges
h=d*(j-f)/2/j+sqr(f*f+(d*d*f*f)/(4*j*j))  ! internal edges
 for v=0 to 2
 put d*(v+1)+i*v,d,15,
    (d+i)*(v+1),d,15,
    (d+i)*(v+1),d+3*j,15,
    d*(v+1)+i*v,d+3*j,15,
    d*(v+1)+i*v,d,-1,

    d*(v+1)+i*v,2*d+3*j,15,
    (d+i)*(v+1),2*d+3*j,15,
    (d+i)*(v+1),2*(d+3*j),15,
    d*(v+1)+i*v,2*(d+3*j),15,
    d*(v+1)+i*v,2*d+3*j,-1
  next v
prism_ 20+nsp/3,c,
0,0,15,
0,b,15,
a,b,15,
a,0,15,
0,0,-1,

get (nsp),

d,b-d-j,15,
d,b-3*d/2,15,
d+i, b-d,15,
d+i,b-d-j,15,
d,b-d-j,-1,

2*d+i,b-d-j,15,
2*d+i,b-d,15,
a-(2*d+i),b-d,15,
a-(2*d+i),b-d-j,15,
2*d+i,b-d-j,-1,

a-d,b-d-j,15,
a-d-i,b-d-j,15,
a-d-i, b-d,15,
a-d,b-3*d/2,15,
a-d,b-d-j,-1

add d,d,c/4
   for v=0 to 2
      addx v*(i+d)
      call door_int_frame i,3*j, c/2, f
      addy 3*j+d
      call door_int_frame i,3*j, c/2, f
      del 2
   next v
addy 6*j+2*d
prism_ 10,c/2,
0,0,15,
0,j-d/2,15,
i,j,15,
i,0,15,
0,0,-1,
f,f,15,
i-f,f,15,
i-f,j-g,15,
f,j-h,15,
f,f,-1
addx d+i
call door_int_frame  i, j, c/2, f
addx d+i
prism_ 10,c/2,
0,0,15,
0,j,15,
i,j-d/2,15,
i,0,15,
0,0,-1,
f,f,15,
i-f,f,15,
i-f,j-h,15,
f,j-g,15,
f,f,-1

del top
addz c/4+c/8
material e                     ! ***fill
 for v=0 to 2
   prism_ 4,0.004,
    d*(v+1)+i*v+f,d+f,15,
    (d+i)*(v+1)-f,d+f,15,
    (d+i)*(v+1)-f,d+3*j-f,15,
    d*(v+1)+i*v+f,d+3*j-f,15
   prism_ 4,0.004,
    d*(v+1)+i*v+f,2*d+3*j+f,15,
    (d+i)*(v+1)-f,2*d+3*j+f,15,
    (d+i)*(v+1)-f,2*(d+3*j)-f,15,
    d*(v+1)+i*v+f,2*(d+3*j)-f,15
 next v
prism_ 4,0.004,
d+f,b-d-j+f,15,
d+f,b-d-h,15,
d+i-f, b-d-g,15,
d+i-f,b-d-j+f,15
prism_ 4,0.004,
2*d+i+f,b-d-j+f,15,
2*d+i+f,b-d-f,15,
a-(2*d+i)-f,b-d-f,15,
a-(2*d+i)-f,b-d-j+f,15
prism_ 4,0.004,
a-d-f,b-d-j+f,15,
a-d-i+f,b-d-j+f,15,
a-d-i+f, b-d-g,15,
a-d-f,b-d-h,15
end












